math-programming/flake.nix at main · prsteele/math-programming · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
{
  description = "A collection of libraries for mathematical programming";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    systems.url = "github:nix-systems/default";
  };

  outputs = { self, nixpkgs, systems }:
    let
      forAllSystems = nixpkgs.lib.genAttrs (import systems);
      mkPkgs = system: import nixpkgs { inherit system; overlays = [ self.overlays.default ]; };
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = mkPkgs system;
        in
        { });

      devShells = forAllSystems (system:
        let
          pkgs = mkPkgs system;
        in
        {
          default = pkgs.haskellPackages.shellFor {
            packages = hpkgs: with hpkgs; [
              examples
              glpk-headers
              math-programming
              math-programming-glpk
              math-programming-tests
            ];
            buildInputs = with pkgs; [
              haskellPackages.haskell-language-server
              ormolu
              cabal-install
            ];
            withHoogle = true;
          };
        });

      overlays = {
        default = final: prev: {
          haskellPackages = prev.haskellPackages.override {
            overrides = hfinal: hprev: {
              examples = hfinal.callCabal2nix "examples" ./examples { };
              glpk-headers = hfinal.callCabal2nix "glpk-headers" ./glpk-headers { };
              math-programming = hfinal.callCabal2nix "math-programming" ./math-programming { };
              math-programming-glpk = hfinal.callCabal2nix "math-programming-glpk" ./math-programming-glpk { };
              math-programming-tests = hfinal.callCabal2nix "math-programming-tests" ./math-programming-tests { };
            };
          };
        };
      };
    };
}