SPAROL 現行の学習指導要領の教科書一覧を取り出したいがなぜか高校が出力されない。

[yegusa]

SPARQL 現行の学習指導要領の教科書一覧を取り出したくて、

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX textbook: <https://w3id.org/jp-textbook/>
PREFIX schema: <http://schema.org/>

SELECT ?s ?title ?publisher ?subject ?grades
WHERE {
  {
    SELECT ?s (GROUP_CONCAT(?grade; SEPARATOR=", ") AS ?grades)
    WHERE {
      ?s a textbook:Textbook .
      ?s textbook:grade ?grade .
    }
    GROUP BY ?s
  }
  ?s schema:publisher ?publisher .
  ?s schema:name ?title .
  ?s textbook:subject ?subject .
  ?s textbook:curriculum ?curriculum .
  FILTER(
    ?curriculum IN (
      <https://w3id.org/jp-textbook/curriculum/小学校/2020>,
      <https://w3id.org/jp-textbook/curriculum/中学校/2021>,
      <https://w3id.org/jp-textbook/curriculum/高等学校/2022>
    )
  )
}

としてみた。小学校と中学校はちゃんと出力されるのだけど、
なぜか、高等学校の教科書だけが出力されない。

なぜ？　どうやったらうまくいくのだろう。

[masao]

学年 (grade) が存在しない場合にヒットしないのを OPTIONAL で回避する必要がありそうです：

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX textbook: <https://w3id.org/jp-textbook/>
PREFIX schema: <http://schema.org/>

SELECT ?s ?title ?publisher ?subject (GROUP_CONCAT(?grade; SEPARATOR=", ") AS ?grades)
WHERE {
  ?s a textbook:Textbook .
  ?s schema:publisher ?publisher .
  ?s schema:name ?title .
  ?s textbook:subject ?subject .
  ?s textbook:curriculum ?curriculum .
  FILTER(
    ?curriculum IN (
      <https://w3id.org/jp-textbook/curriculum/小学校/2020>,
      <https://w3id.org/jp-textbook/curriculum/中学校/2021>,
      <https://w3id.org/jp-textbook/curriculum/高等学校/2022>
    )
  )
  OPTIONAL { ?s textbook:grade ?grade . }
}
GROUP BY ?s ?title ?publisher ?subject