Merge remote-tracking branch 'upstream/main'

Author: Dreeam-qwq

.gitignore

@@ -6,8 +6,7 @@
 ## environment <--
 
 ## build -->
-target
 *.iml
 build
 .gradle
-## build <--
+## build <--

README.md

@@ -19,12 +19,10 @@ git clone https://github.com/Gecolay/GSit.git
 
 ### Build
 
-Run the maven build command by your ide or in a terminal.
+Run the `gradle build` command.
 
-`mvn clean package`
-
-The final `GSit-x.x-x.jar` file will be in the [`target`](./target) folder.
+The final `GSit-x.x-x.jar` file will be in the [`build/libs`](./build/libs) folder.
 
 ## Pull requests
 
-You can create a pull request to submit your code to this repository: [Pull requests](https://github.com/Gecolay/GSit/pulls)
+You can create a pull request to submit your code to this repository: [Pull requests](https://github.com/Gecolay/GSit/pulls)

build.gradle.kts

@@ -0,0 +1,85 @@
+plugins {
+    `java-library`
+    `maven-publish`
+    id("com.gradleup.shadow") version "9.0.0-beta11"
+    id("io.papermc.paperweight.userdev") version "2.0.0-beta.16" apply false
+}
+
+allprojects {
+    apply(plugin = "java-library")
+
+    repositories {
+        mavenLocal()
+        mavenCentral()
+
+        maven(url = "https://repo.papermc.io/repository/maven-public/")
+        maven(url = "https://maven.enginehub.org/repo/")
+        maven(url = "https://repo.extendedclip.com/content/repositories/placeholderapi/")
+        maven(url = "https://jitpack.io/")
+    }
+
+    tasks.compileJava {
+        options.encoding = "UTF-8"
+    }
+
+    tasks.javadoc {
+        options.encoding = "UTF-8"
+    }
+}
+
+dependencies {
+    api(project(":core"))
+    api(project(":v1_17_1", configuration = "reobf"))
+    api(project(":v1_18", configuration = "reobf"))
+    api(project(":v1_18_2", configuration = "reobf"))
+    api(project(":v1_19", configuration = "reobf"))
+    api(project(":v1_19_1", configuration = "reobf"))
+    api(project(":v1_19_3", configuration = "reobf"))
+    api(project(":v1_19_4", configuration = "reobf"))
+    api(project(":v1_20", configuration = "reobf"))
+    api(project(":v1_20_2", configuration = "reobf"))
+    api(project(":v1_20_3", configuration = "reobf"))
+    api(project(":v1_20_5", configuration = "reobf"))
+    api(project(":v1_21", configuration = "reobf"))
+    api(project(":v1_21_2", configuration = "reobf"))
+    api(project(":v1_21_4", configuration = "reobf"))
+}
+
+tasks {
+    shadowJar {
+        archiveClassifier = ""
+        minimize()
+        manifest {
+            attributes["paperweight-mappings-namespace"] = "spigot"
+        }
+    }
+
+    build {
+        dependsOn(shadowJar)
+    }
+
+    compileJava {
+        options.release = 16
+    }
+
+    processResources {
+        from("resources")
+        expand(
+            "name" to project.name,
+            "version" to project.version,
+            "description" to project.description,
+            "main" to "${project.group}.${project.name}Main"
+        )
+    }
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("maven") {
+            groupId = project.group.toString()
+            artifactId = project.name
+            version = project.version.toString()
+            from(project.components["java"])
+        }
+    }
+}

core/build.gradle.kts

@@ -0,0 +1,35 @@
+plugins {
+    `maven-publish`
+}
+
+dependencies {
+    compileOnly("io.papermc.paper:paper-api:1.21.4-R0.1-SNAPSHOT")
+    compileOnly("com.sk89q.worldguard:worldguard-bukkit:7.0.13") {
+        exclude("com.google.guava", "guava")
+        exclude("com.google.code.gson", "gson")
+        exclude("it.unimi.dsi", "fastutil")
+    }
+    compileOnly("me.clip:placeholderapi:2.11.6")
+    compileOnly("com.github.GriefPrevention:GriefPrevention:16.18.4")
+    compileOnly("com.intellectualsites.plotsquared:plotsquared-core:7.5.1")
+}
+
+java {
+    disableAutoTargetJvm()
+    toolchain.languageVersion = JavaLanguageVersion.of(21)
+}
+
+tasks.compileJava {
+    options.release = 16
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("maven") {
+            groupId = project.group.toString()
+            artifactId = project.name
+            version = project.version.toString()
+            from(project.components["java"])
+        }
+    }
+}