Gaussian blur postprocessing

Author: Pilzschaf

shaders/compile.bat

@@ -7,4 +7,6 @@ glslc.exe -fshader-stage=frag texture_frag.glsl -o texture_frag.spv
 glslc.exe -fshader-stage=vert model_vert.glsl -o model_vert.spv
 glslc.exe -fshader-stage=frag model_frag.glsl -o model_frag.spv
 glslc.exe -fshader-stage=vert postprocess_vert.glsl -o postprocess_vert.spv
-glslc.exe -fshader-stage=frag postprocess_frag.glsl -o postprocess_frag.spv
+glslc.exe -fshader-stage=frag postprocess_frag.glsl -o postprocess_frag.spv
+glslc.exe -fshader-stage=vert gaussian_vert.glsl -o gaussian_vert.spv
+glslc.exe -fshader-stage=frag gaussian_frag.glsl -o gaussian_frag.spv

shaders/compile.sh

@@ -8,4 +8,6 @@ glslc -fshader-stage=frag texture_frag.glsl -o texture_frag.spv
 glslc -fshader-stage=vert model_vert.glsl -o model_vert.spv
 glslc -fshader-stage=frag model_frag.glsl -o model_frag.spv
 glslc -fshader-stage=vert postprocess_vert.glsl -o postprocess_vert.spv
-glslc -fshader-stage=frag postprocess_frag.glsl -o postprocess_frag.spv
+glslc -fshader-stage=frag postprocess_frag.glsl -o postprocess_frag.spv
+glslc -fshader-stage=vert gaussian_vert.glsl -o gaussian_vert.spv
+glslc -fshader-stage=frag gaussian_frag.glsl -o gaussian_frag.spv

shaders/gaussian_frag.glsl

@@ -0,0 +1,33 @@
+#version 450 core
+
+// Two pass gaussian blur
+// https://www.rastergrid.com/blog/2010/09/efficient-gaussian-blur-with-linear-sampling/
+
+layout(binding = 0) uniform sampler2D colorTex;
+
+layout(location = 0) in vec2 texCoord;
+layout (location = 0) out vec4 outColor;
+
+layout(constant_id = 0) const bool VERTICAL = false;
+
+layout(push_constant) uniform pushConstants {
+	float pixelSize; // pixel size eg. 1 / screenWidth and 1 / screenHeight
+} u_pushConstants;
+
+float offset[3] = float[](0.0, 1.3846153846, 3.2307692308);
+float weight[3] = float[](0.2270270270, 0.3162162162, 0.0702702703);
+
+void main(void) {
+    outColor = texture(colorTex, texCoord) * weight[0];
+    for (int i=1; i<3; i++) {
+        
+        if(VERTICAL) {
+            outColor += texture(colorTex, (vec2(texCoord) + vec2(0.0, offset[i] * u_pushConstants.pixelSize))) * weight[i];
+            outColor += texture(colorTex, (vec2(texCoord) - vec2(0.0, offset[i] * u_pushConstants.pixelSize))) * weight[i];
+        } else {
+            // Horizontal
+            outColor += texture(colorTex, (vec2(texCoord) + vec2(offset[i] * u_pushConstants.pixelSize, 0.0))) * weight[i];
+            outColor += texture(colorTex, (vec2(texCoord) - vec2(offset[i] * u_pushConstants.pixelSize, 0.0))) * weight[i];
+        }
+    }
+}

shaders/gaussian_frag.spv

@@ -0,0 +1,35 @@
+#version 450 core
+
+//Basic Buffer/Layout-less fullscreen triangle vertex shader
+vec2 triangleVertex(in int vertID, out vec2 texcoord) {
+    /*
+    //See: https://web.archive.org/web/20140719063725/http://www.altdev.co/2011/08/08/interesting-vertex-shader-trick/
+       1
+    ( 0, 2)
+    [-1, 3]   [ 3, 3]
+        .
+        |`.
+        |  `.
+        |    `.
+        '------`
+       0         2
+    ( 0, 0)   ( 2, 0)
+    [-1,-1]   [ 3,-1]
+    ID=0 -> Pos=[-1,-1], Tex=(0,0)
+    ID=1 -> Pos=[-1, 3], Tex=(0,2)
+    ID=2 -> Pos=[ 3,-1], Tex=(2,0)
+    */
+
+    texcoord.x = (vertID == 2) ?  2.0 :  0.0;
+    texcoord.y = (vertID == 1) ?  2.0 :  0.0;
+
+	return texcoord * vec2(2.0, -2.0) + vec2(-1.0, 1.0);
+}
+
+layout(location = 0) out vec2 texCoord;
+
+void main(void) {
+    vec2 pos = triangleVertex(gl_VertexIndex, texCoord);
+
+    gl_Position = vec4(pos, 1.0, 1.0);
+}