BSPP G1/2" screw hole

[pfelecan]

Hello,
I'm trying to make a screw hole for a threaded BSPP G1/2" with no avail.
What disturbs me is that a G1/2" is not a half inch but something as 20.955mm with a 14TPI and 1.818mm step.
I tried with the screws.scad module without success.
Is there a kind souk who can guide me toward a solution in the context of BOSL2?
Thank you in advance

[adrianVmariano]

You need to use generic_threaded_rod and know the geometry of your threads. There is no support for that threading standard. Also screws.scad is just screws. Threading is in threading.scad.

[pfelecan]

You're right, it's about threads, not screws.
I'll try to figure out how to implement this in the context of BOSL2.
Thank you for your help

[pfelecan]

I'm trying to use the thread_rod module and I'm a little bit confused about the parameters:
if d is a triplet, d[1] is the pitch, but there is also a parameter pitch which is mandatory, thus there seems to be a redundancy, or I'm not understanding the difference.

[pfelecan]

Well, I need better glasses... d[1] is d_pitch, which I suppose is diameter pitch
Anyhow, I succeeded to make a BSP G1/2 thread which fits well.

[adrianVmariano]

I'm a bit puzzled because threaded_rod produces ISO threading which is a 60 deg angle but when I looked up BSPP I found that it has a 55 deg angle not 60. https://www.machiningdoctor.com/threadinfo-bspp-new/?tid=4706

So that means to make it you have to create a new thread profile and use generic_threaded_rod, or perhaps you could get away with trapezoidal_threaded_rod.

[pfelecan]

Yes, I can confirm that, see this calculator.
My current solution works for the moment even if it's incorrect per se.
I'll try to use generic_threaded_rod but guidance, i.e. example, would be nice.

[adrianVmariano]

There are examples in the wiki. Are they insufficient? There's a diagram showing an ISO thread form there.

[pfelecan]

Hello,
I worked a little bit on an implementation of BSPP rods following ISO 228 G and BSW standard used by.
The only, minor, difficulty was the rounding for the peak and valleys in the profile.
I would like to show the code for review. If interested, how do you prefer to do it: pasting the code here or creating a pull request ? The later is quite labored but can do it.
My intention is, that after review and testing, to donate it for integration if there is an interest.

[adrianVmariano]

You can paste it here.

[pfelecan]

Here is my code. For the moment only the dimensions for the 1/2 pipe is given.
Thank you in advance for your comments, suggestions, &c.

/*
  $Id: BSPP.scad 21 2026-01-04 14:57:49Z peter $

  British Standard Pipe Parallel, i.e. "Pipe thread ISO 228 G"

  References:

  1. [[https://en.wikipedia.org/wiki/British_Standard_Pipe][Wikipedia]]

  2.[[https://en.wikipedia.org/wiki/British_Standard_Whitworth#Thread_form]]

  The form of a Whitworth thread is based on a fundamental triangle
  with an angle of 55° at each peak and valley. The sides are at a
  flank angle of Θ = 27.5° perpendicular to the axis. Thus, if the
  thread pitch is p, the height of the fundamental triangle is H =
  p/(2tanΘ) = 0.96049106p. However, the top and bottom 1/6 of each of
  these triangles is cut off, so the actual depth of thread (the
  difference between major and minor diameters) is 2/3 of that value,
  or h = p/(3tanΘ) = 0.64032738p. The peaks are further reduced by
  rounding them with a 2×(90° − Θ) = 180° − 55° = 125° circular
  arc. This arc has a height of e = Hsin Θ/6 = 0.073917569p (leaving a
  straight flank depth of h − 2e = 0.49249224p) and a radius of r =
  e/(1 − sin Θ) = 0.13732908p.

  3. [[https://en.wikipedia.org/wiki/File:Whitworth_Thread.svg]]
  
  4. [[https://amesweb.info/Screws/bspp-thread-chart-calculator.aspx][Calculator]]

  5. [[https://amesweb.info/Screws/Images/British-Pipe-Thread/BSPP.jpg][Diagram]]
  
  Copyright (C) 2026 Peter Felecan peter@felecan.org

  This file is part of BSPP.

  BSPP  is free software: you can redistribute it and/or modify it
  under the terms of the GNU General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  BSPP is distributed in the hope that it will be useful, but
  WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  General Public License for more details.

  You should have received a copy of the GNU General Public License
  along with BSPP. If not, see <http://www.gnu.org/licenses/>.
*/
include <BOSL2/std.scad>
include <BOSL2/structs.scad>
include <BOSL2/threading.scad>
$slop = ((is_undef($slop)) ? 0.3 : $slop); // PETG
function bspp_dimensions(size) =
	assert(!is_undef(size), "undefined size")
	assert(is_string(size), "size is not a string")
	assert(
		in_list(
			size,
				[
					"1/16",
					"1/8",
					"1/4",
					"3/8",
					"1/2",
					"5/8",
					"3/4",
					"7/8",
					"1"
					]
			),
			str("unknown size \"", size, "\"")
		)
	size == "1/2"
	?
	struct_set(
		[],
		[
			"pitch", 0.825,
			"Diameter", 20.955,
			"diameter", 18.631,
			"gauge", 8.2
			]
		)
	:
	undef
	;
function bspp_threaded_rod(
	size,
    left_handed=false, starts=1,
    bevel,bevel1,bevel2,
    internal=false,
    length, height,
    blunt_start, blunt_start1, blunt_start2,
    lead_in, lead_in1, lead_in2,
    lead_in_ang, lead_in_ang1, lead_in_ang2,
    end_len, end_len1, end_len2,
    lead_in_shape="default",
    anchor, spin, orient
) = no_function("bspp_threaded_rod");
module bspp_threaded_rod(
	size,
    left_handed=false, starts=1,
    bevel,bevel1,bevel2,
    internal=false,
    length, height,
    blunt_start, blunt_start1, blunt_start2,
    lead_in, lead_in1, lead_in2,
    lead_in_ang, lead_in_ang1, lead_in_ang2,
    end_len, end_len1, end_len2,
    lead_in_shape="default",
    anchor, spin, orient
	)
{
	function CirclePoint(a, b, r, t) = [a + r * cos(t), b + r * sin(t)];
	dimension = bspp_dimensions(size);
	p = struct_val(dimension, "pitch");
	d = struct_val(dimension, "Diameter");
	theta = 55 / 2;
	t = 1/6;                      // : truncation
	H = p / (2 * tan(theta));     // : fundamental triangle height
	h = 2 * H / 3;                // : actual depth of the thread
	e = H * sin(theta) / 6;       // : rounding arc's height
	r = e / (1 - sin(theta));     // : rounding arc's radius
	s = h - 2 * e;                // : straight flank depth
	c = tan(theta) * (H / 6 + e); // : crest's half width
	lStart = [-p / 2, -h];
	lEnd = [-(p / 2 - tan(theta) * (H / 6 + e)), -h + e];
	uStart = [-c, -e];
	uEnd = [c, -e];
	rStart = [(p / 2 - tan(theta) * (H / 6 + e)), -h + e];
	rEnd = [p / 2, -h];
	urProfile = [
		lStart,
		lEnd,
		uStart,
		[0, 0],
		uEnd,
		rStart,
		rEnd,
		];
	//stroke(urProfile, width = 0.01, joints = "dot");
	arc = p / 2;
	brc = -(h - r);
	function rCompare(e, a, b, r, t) =
		CirclePoint(a, b, r, t).y <= e.y
		? true
		: false;
	rCircle = [
		for(
			A = 270;
			A >= 180 && rCompare(rStart, arc, brc, r, A);
			A = A - 360 / (($fn) ? $fn : $fa)
			)
			CirclePoint(arc, brc, r, A)
		];
	/* stroke( */
	/* 	rCircle, */
	/* 	width = 0.01, */
	/* 	color = "cyan" */
	/* 	); */
	auc = 0;
	buc = -r;
	function uCompare(e, a, b, r, t) =
		CirclePoint(a, b, r, t).y >= e.y
		? true
		: false;
	urCircle = [
		for(
			A = 90;
			A >= 0 && uCompare(uEnd, auc, buc, r, A);
			A = A - 360 / (($fn) ? $fn : $fa)
			)
			CirclePoint(auc, buc, r, A)
		];
	/* stroke( */
	/* 	urCircle, */
	/* 	width = 0.01, */
	/* 	color = "cyan" */
	/* 	); */
	ulCircle = [
		for(
			A = 90;
			A <= 180 && uCompare(uStart, auc, buc, r, A);
			A = A + 360 / (($fn) ? $fn : $fa)
			)
			CirclePoint(auc, buc, r, A)
		];
	/* stroke( */
	/* 	ulCircle, */
	/* 	width = 0.01, */
	/* 	color = "cyan" */
	/* 	); */
	alc = -p / 2;
	blc = -(h - r);
	function lCompare(e, a, b, r, t) =
		CirclePoint(a, b, r, t).x <= e.x
		&& CirclePoint(a, b, r, t).y <= e.y
		? true
		: false;
	lCircle = [
		for(
			A = 270;
			A <= 360 && lCompare(lEnd, alc, blc, r, A);
			A = A + 360 / (($fn) ? $fn : $fa)
			)
			CirclePoint(alc, blc, r, A)
		];
	/* stroke( */
	/* 	lCircle, */
	/* 	width = 0.01, */
	/* 	color = "cyan" */
	/* 	); */
	lFlank = [
		lEnd,
		uStart
		];
	rFlank = [
		uEnd,
		rStart
		];
	profile = concat(
		lCircle,
		lFlank,
		reverse(ulCircle),
		urCircle,
		rFlank,
		reverse(rCircle)
		);
	//stroke(profile, width = 0.01, color = "cyan");
	generic_threaded_rod(
		d = d, length = length, height = height,
		pitch = p, profile = profile,
        left_handed=left_handed,
        bevel=bevel,bevel1=bevel1,bevel2=bevel2,
        internal=internal,
        blunt_start=blunt_start, blunt_start1=blunt_start1, blunt_start2=blunt_start2,
        lead_in=lead_in, lead_in1=lead_in1, lead_in2=lead_in2, lead_in_shape=lead_in_shape,
        lead_in_ang=lead_in_ang, lead_in_ang1=lead_in_ang1, lead_in_ang2=lead_in_ang2,
        end_len=end_len, end_len1=end_len1, end_len2=end_len2,
        anchor=anchor,
        spin=spin,starts=starts,
        orient=orient
		
		)
		children();
}
dimension = bspp_dimensions("1/2");
p = struct_val(dimension, "pitch");
d = struct_val(dimension, "Diameter");
up(p / 2)
difference()
{
	color("blue") bspp_threaded_rod("1/2", length = 10);
	cuboid([d, d, 10], anchor = BACK);
}
difference()
{
	color("white") cuboid([30, 30, 10]);
	bspp_threaded_rod("1/2", length = 10, internal = true, $slop = .1);
	cuboid([d + 10, d + 10, 10], anchor = BACK);
}